/*T: EDI - Outbound 940 Warehouse Shipping Order - Hdr  - Physical File
     H*
     M*=========================================================================
     M* Maintenance   :
     M*=========================================================================
     A*=========================================================================
     A          R EDOWOHR                   TEXT('EDOWOHR')
     A*-------------------------------------------------------------------------
     A            OHDEL      00001A         TEXT('Status Code')
     A            OHCMP      00003S         TEXT('COMPANY #')
     A            OHEDOC     00010A         TEXT('ELECTRONIC DOC #')
     A            OHCUST     00007A         TEXT('CUSTOMER #')
     A            OHOSC      00001A         TEXT('W0501 - Order status code')
     A            OHPTN      00022A         TEXT('W0502 - Pick ticket nbr')
     A            OHPONO     00022A         TEXT('W0503 - Purchase Order')
     A            OHDEPT     00010A         TEXT('N902 - Department')
     A            OHMRTP     00010A         TEXT('N902 - Merchandise Type')
     A            OHPOEV     00010A         TEXT('N902 - PO Event')
     A            OHIVND     00010A         TEXT('N902 - Internal Vendor')
     A            OHASPO     00010A         TEXT('N902 - Associated PO')
     A            OHINV      00010A         TEXT('N902 - Invoice Number')
     A            OHSTRU     00010A         TEXT('N902 - Structure Code')
     A            OHLOC      00004A         TEXT('N902 - Inventory Location')
     A            OHCNDT     00008S         TEXT('G6202 - Cancel After Date')
     A            OHCNTM     00006S         TEXT('G6204 - Cancel After Time')
     A            OHRDDT     00008S         TEXT('G6202 - Delivery Rqst Date')
     A            OHDRTM     00006S         TEXT('G6204 - Delivery Rqst Time')
     A            OHRSDT     00008S         TEXT('G6202 - Request Ship Date')
     A            OHRSTM     00006S         TEXT('G6204 - Request Ship Time')
     A            OHSBDT     00008S         TEXT('G6202 - Ship Not B4 Date')
     A            OHSBTM     00006S         TEXT('G6204 - Ship Not B4 Time')
     A            OHSLDT     00008S         TEXT('G6202 - Ship Not Ltr Date')
     A            OHSLTM     00006S         TEXT('G6204 - Ship Not Ltr Time')
     A            OHMADT     00008S         TEXT('G6202 - Must Arr By Date')
     A            OHMATM     00006S         TEXT('G6204 - Must Arr By Time')
     A            OHTUNT     00007S         TEXT('W7601 - Total Quantity')
     A            OHPRID     00015A         TEXT('Trading Partner Id')
     A            OHPRQL     00025A         TEXT('Trading Partner QL')
     A            OHEDDT     00008S         TEXT('Transmission Date')
     A            OHEDTM     00006S         TEXT('Transmission Time')
     A            OHEDPT     00001A         TEXT('Test/Production')
     A            OHEDIC     00010A         TEXT('Interchange Control#')
     A            OHEDGC     00010A         TEXT('Group Control#')
     A            OHEDTC     00010A         TEXT('Trans Control#')
     A            OHEDST     00010A         TEXT('Document ID')
     A            OHEDFT     00010A         TEXT('Map Name')
     A            OHAFS      00010A         TEXT('App File Set')
     A            OHGRP      00010A         TEXT('Document Group')
     A            OHEDPF     00001A         TEXT('Processed Flag')
     A            OHCCTD     00008S         TEXT('Creation Date')
     A            OHCCTT     00006S         TEXT('Creation Time')
     A            OHCCTU     00010A         TEXT('Creation User')
     A            OHCCTP     00010A         TEXT('Creation PGM')
     A            OHLCGD     00008S         TEXT('Change Date')
     A            OHLCGT     00006S         TEXT('Change Time')
     A            OHLCGU     00010A         TEXT('Change User')
     A            OHLCGP     00010A         TEXT('Change PGM')
     A            OHCAC      00004A         TEXT('SHIP VIA CODE')
     A            OHCAN      00035A         TEXT('SHIP VIA DESCRIPTION')
     A            OHREF25    00030A         TEXT('N902 Reference ID')
     A            OHREFST    00017A         TEXT('N902 Ship To')
     A            OHWGHT     00011P04       TEXT('W7602 - Weight')
     A            OHVOL      00011P04       TEXT('W7604 - Volume')
     A*=========================================================================